dwelling-radio/build/archlinux/PKGBUILD

# Maintainer: Alexander "Arav" Andreev <me@arav.su>
pkgname=dwelling-radio
pkgver=23.33.2
pkgrel=1
pkgdesc="Arav's dwelling / Radio"
arch=('i686' 'x86_64' 'arm' 'armv6h' 'armv7h' 'aarch64')
url="https://git.arav.su/Arav/dwelling-radio"
license=('MIT')
makedepends=('go>=1.17')
optdepends=(
    'tree: to make a filelist html file'
    'ffmpeg: to convert media to ogg and get duration of songs')
provides=('dwelling-radio')
conflicts=('dwelling-radio')
backup=('etc/dwelling/radio.vars.liq')
source=("${pkgver}.tar.gz::https://git.arav.su/Arav/dwelling-radio/archive/v${pkgver}.tar.gz")
md5sums=('SKIP')

build() {
    cd "$srcdir/$pkgname"
    export GOPATH="$srcdir"/gopath
    export CGO_CPPFLAGS="${CPPFLAGS}"
    export CGO_CFLAGS="${CFLAGS}"
    export CGO_CXXFLAGS="${CXXFLAGS}"
    export CGO_LDFLAGS="${LDFLAGS}"
    make VERSION=$pkgver DESTDIR="$pkgdir" PREFIX="/usr"
}

package() {
    cd "$srcdir/$pkgname"
    make DESTDIR="$pkgdir" PREFIX="/usr" install
}